home *** CD-ROM | disk | FTP | other *** search
/ Scene 96 / Scene 96 International Edition (Zyklop Software) (Disc 2) (1997).iso / graphics / artpacks / acid0896 / stm.pas < prev    next >
Pascal/Delphi Source File  |  1996-07-31  |  9KB  |  273 lines
  1. {$A+,B-,D+,E+,F-,G-,I+,L+,N-,O-,P-,Q-,R-,S-,T-,V-,X+,Y+}
  2. UNIT STM;
  3. {=============================================================================
  4.  
  5.   Unit STreaMs
  6.  
  7.   Provides buffered input/output for untyped files.
  8.  
  9.   Purpose :
  10.     Accessing files with small records can slow down a program dramatically
  11.     due to overhead when chaining to the DOS INT 21h handler.  By buffering
  12.     all reads and writes, thereby reducing the number of calls to the INT 21h
  13.     handler, we can gain a significant amount of speed increase at an
  14.     acceptable cost of increased memory use.
  15.  
  16.     Files are split up into blocks of STM_BufSize bytes, these blocks are
  17.     called 'pages'.  As needs predict, the stream will read the appropriate
  18.     page in memory, and copy the required data out of the buffer.
  19.  
  20.   The STM unit strongly resembles the C 'FILE' type.  STM is however
  21.   somewhat simpler since it provides no way for altering the buffer size
  22.   (other than changing the STM_BufSize constant and recompiling), and always
  23.   works by reading data on STM_BufSize boundaries.
  24.  
  25. =============================================================================}
  26.  
  27. {▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀}
  28.                                 INTERFACE
  29. {▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄}
  30.  
  31. USES DOS;
  32.  
  33. CONST  STM_BufSize = 4096;                   { Multiples of 2 are best       }
  34.  
  35. TYPE   OpenFlag    = (NOCREATE, CREATE, CREATENEW);
  36.  
  37. TYPE   STM_Buffer  = ARRAY [0..STM_BufSize-1] OF BYTE;
  38.        STM_BufPtr  = ^STM_Buffer;
  39.        STM_Error   = (STM_OK,                { No error                      }
  40.                       STM_NOMEM,             { Insufficient memory for buffer}
  41.                       STM_OPENERROR,         { Open/create did not succeed   }
  42.                       STM_SEEKERROR,         { Error seeking to location     }
  43.                       STM_READERROR,         { Error when reading            }
  44.                       STM_WRITEERROR);       { Error when writing            }
  45.  
  46.  
  47.        STREAM      = RECORD
  48.                        F       : File;       { FILE associated with stream   }
  49.                        BufPtr  : STM_BufPtr; { Pointer to buffer for stream  }
  50.                        PageNr  : LONGINT;    { Page number we're working at  }
  51.                        PageNdx : LONGINT;    { offset within page of current }
  52.                                              { file pointer                  }
  53.                        PageLen : LONGINT;    { Actual length of buffer read  }
  54.                                              { from disk.  will be equal to  }
  55.                                              { STM_BufSize except for the    }
  56.                                              { last page                     }
  57.                        LastErr : STM_Error;  { Last error reported on this   }
  58.                                              { stream                        }
  59.                        Modified: BOOLEAN;    { Has the page been written to? }
  60.                      END;
  61.  
  62. PROCEDURE STM_Open   (VAR S : STREAM; CONST FName : NameStr; CONST Flag : OpenFlag);
  63. PROCEDURE STM_Create (VAR S : STREAM; CONST FName : NameStr);
  64. PROCEDURE STM_Close  (VAR S : STREAM);
  65. PROCEDURE STM_Write  (VAR S : STREAM; VAR DataBuf; DataLen : Word);
  66. PROCEDURE STM_Read   (VAR S : STREAM; VAR DataBuf; DataLen : Word);
  67. PROCEDURE STM_Flush  (VAR S : STREAM);
  68. PROCEDURE STM_Goto   (VAR S : STREAM; Location : Longint);
  69. FUNCTION  STM_GetPos (VAR S : STREAM) : LongInt;
  70. FUNCTION  STM_GetSize(VAR S : STREAM) : LongInt;
  71.  
  72. {▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀}
  73.                               IMPLEMENTATION
  74. {▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄}
  75.  
  76. { Open a stream.
  77. {  Flag:  NOCREATE : Open a stream but do not create a new file              }
  78. {         CREATE   : Open a stream if possible, create a new file if opening }
  79. {                    did not succeed.                                        }
  80. {         CREATENEW: Create a new file                                       }
  81. PROCEDURE STM_Open   (VAR S : STREAM; CONST FName : NameStr; CONST Flag : OpenFlag);
  82. VAR  IsOpen : BOOLEAN;
  83. BEGIN
  84.   IsOpen:=FALSE;
  85.   FILLCHAR(S,sizeof(S),#0);            { Initialize the stream record        }
  86.  
  87.   IF (MaxAvail<STM_BufSize) THEN BEGIN { Enough memory is available ?        }
  88.      S.LastErr:=STM_NOMEM;
  89.      Exit;
  90.   END;
  91.  
  92.   ASSIGN (S.F,FName);                  { Assign filename to file             }
  93.  
  94.   IF (Flag = NOCREATE) OR (Flag = CREATE) THEN BEGIN
  95.      {$i-}
  96.      Reset(S.F,1);
  97.      {$i+}
  98.      IsOpen:=IOResult=0;
  99.   END;
  100.   IF (NOT IsOpen) AND ((Flag = CREATE) OR (Flag = CREATENEW)) THEN BEGIN
  101.      {$i-}
  102.      Rewrite(S.F,1);
  103.      {$i+}
  104.      IsOpen:=IOResult=0;
  105.   END;
  106.  
  107.   IF NOT IsOpen THEN BEGIN
  108.      S.LastErr:=STM_OPENERROR;
  109.   END
  110.   ELSE BEGIN
  111.      New(S.BufPtr);
  112.      S.PageNr:=-1;                     { Make sure we'll be actually reading }
  113.                                        { a new page                          }
  114.      STM_Goto(S,0);                    { and position at start of file       }
  115.   END;
  116. END;
  117.  
  118.  
  119. { Create a stream }
  120. PROCEDURE STM_Create (VAR S : STREAM; CONST FName : NameStr);
  121. BEGIN
  122.   STM_Open(S,FName,CREATENEW);
  123. END;
  124.  
  125.  
  126. { Close a stream }
  127. PROCEDURE STM_Close  (VAR S : STREAM);
  128. BEGIN
  129.   STM_Flush(S);                        { Force any modified data to disk     }
  130.   Close(S.F);                          { Close the file                      }
  131.   Dispose(S.BufPtr);                   { Free the memory                     }
  132. END;
  133.  
  134.  
  135. { Write the buffered data to disk }
  136. PROCEDURE STM_Flush  (VAR S : STREAM);
  137. VAR BytesWritten : Word;
  138. BEGIN
  139.   IF (S.Modified) THEN BEGIN           { Is there any modified data ?        }
  140.      {$I-}
  141.      Seek(S.F, S.PageNr*STM_BufSize);  { Seek to start of current page       }
  142.      {$I+}
  143.      IF (IOResult<>0) THEN BEGIN
  144.         S.LastErr:=STM_SEEKERROR;
  145.         Exit;
  146.      END;
  147.  
  148.                                        { Write page                          }
  149.      BlockWrite(S.F, S.BufPtr^, S.PageLen, BytesWritten);
  150.      IF (BytesWritten<>S.PageLen) THEN BEGIN
  151.         S.LastErr:=STM_WRITEERROR;
  152.         Exit;
  153.      END;
  154.  
  155.      S.Modified:=FALSE;
  156.   END;
  157.  
  158.   S.LastErr:=STM_OK;
  159. END;
  160.  
  161.  
  162. { Alter the current file pointer (similar to Pascal's Seek) }
  163. PROCEDURE STM_Goto   (VAR S : STREAM; Location : LONGINT);
  164. VAR BytesRead     : Word;
  165.     WantedPageNr  : LongInt;
  166.     WantedPageNdx : LongInt;
  167. BEGIN
  168.   WantedPageNr :=Location DIV STM_BufSize;
  169.   WantedPageNdx:=Location MOD STM_BufSize;
  170.  
  171.   IF (WantedPageNr<>S.PageNr) THEN BEGIN
  172.      STM_Flush(S);                     { Force any modified data to disk     }
  173.      IF (S.LastErr<>STM_OK) THEN Exit;
  174.  
  175.      {$I-}                             { Seek to start of current page       }
  176.      Seek(S.F, WantedPageNr*STM_BufSize);
  177.      {$I+}
  178.      IF (IOResult<>0) THEN BEGIN
  179.         S.LastErr:=STM_SEEKERROR;
  180.         Exit;
  181.      END;
  182.  
  183.                                        { Read page                           }
  184.      BlockRead(S.F, S.BufPtr^, STM_BufSize, BytesRead);
  185.      S.PageLen:=BytesRead;
  186.      IF (WantedPageNdx>S.PageLen) THEN BEGIN
  187.         S.LastErr:=STM_SEEKERROR;
  188.         Exit;
  189.      END;
  190.      S.PageNdx:=WantedPageNdx;
  191.      S.PageNr :=WantedPageNr;
  192.   END
  193.   ELSE
  194.      S.PageNdx:=WantedPageNdx;
  195.  
  196.   S.LastErr:=STM_OK;
  197. END;
  198.  
  199.  
  200. { Write some data to the stream, not necessarily writing to disk }
  201. PROCEDURE STM_Write  (VAR S : STREAM; VAR DataBuf; DataLen : Word);
  202. VAR BytePtr : ^Byte;
  203.     Len     : Word;
  204. BEGIN
  205.   IF (S.LastErr<>STM_OK) THEN RunError(5);
  206.  
  207.   BytePtr:=@DataBuf;
  208.   WHILE (DataLen>0) AND (S.LastErr=STM_OK) DO BEGIN
  209.      IF (S.PageNdx+DataLen>STM_BufSize) THEN
  210.         Len:=STM_BufSize-S.PageNdx
  211.      ELSE
  212.         Len:=DataLen;
  213.  
  214.      Move(BytePtr^,S.BufPtr^[S.PageNdx],Len);
  215.      S.Modified:=TRUE;
  216.  
  217.      Dec(DataLen,Len);
  218.      Inc(BytePtr,Len);
  219.      Inc(S.PageNdx,Len);
  220.  
  221.      IF (S.PageLen<S.PageNdx) THEN
  222.         S.PageLen:=S.PageNdx;
  223.  
  224.      IF (DataLen>0) OR (S.PageNdx=STM_BufSize) THEN
  225.         STM_Goto(S,(S.PageNr+1)*STM_BufSize);
  226.   END;
  227. END;
  228.  
  229.  
  230. { Read some data from the stream }
  231. PROCEDURE STM_Read   (VAR S : STREAM; VAR DataBuf; DataLen : Word);
  232. VAR BytePtr : ^Byte;
  233.     Len     : Word;
  234. BEGIN
  235.   IF (S.LastErr<>STM_OK) THEN RunError(5);
  236.  
  237.   BytePtr:=@DataBuf;
  238.   WHILE (DataLen>0) AND (S.LastErr=STM_OK) DO BEGIN
  239.      IF (S.PageNdx+DataLen>STM_BufSize) THEN
  240.         Len:=STM_BufSize-S.PageNdx
  241.      ELSE
  242.         Len:=DataLen;
  243.  
  244.      Move(S.BufPtr^[S.PageNdx],BytePtr^,Len);
  245.  
  246.      Dec(DataLen,Len);
  247.      Inc(BytePtr,Len);
  248.      Inc(S.PageNdx,Len);
  249.  
  250.      IF (DataLen>0) OR (S.PageNdx=STM_BufSize) THEN
  251.         STM_Goto(S,(S.PageNr+1)*STM_BufSize);
  252.   END;
  253. END;
  254.  
  255.  
  256. { Return the current file pointer (similar to Pascal's GetPos) }
  257. FUNCTION  STM_GetPos (VAR S : STREAM) : LongInt;
  258. BEGIN
  259.   STM_GetPos := S.PageNr*STM_BufSize + S.PageNdx;
  260. END;
  261.  
  262.  
  263. { Return the current size of the file }
  264. FUNCTION  STM_GetSize(VAR S : STREAM) : LongInt;
  265. BEGIN
  266.   STM_Flush(S);                        { Force data to disk first }
  267.   STM_GetSize:= FileSize(S.F);
  268. END;
  269.  
  270.  
  271. END.
  272.  
  273.